Bernoulli Gate for Grains

I have created an Arduino Sketch for GRAINS which provides a Bernoulli Gate module. Inspired by the Branches Module by Mutable Instruments.

Input "A" is used as gate-input. If a gate is detected, the module flips a coin and decides if the gate is sent to output "OUT" or output "D". The probability of the outcome of the coin toss can be influenced by "P1". When P1 is in the middle position, the probability of the coin flip (output "OUT" or output "D") is 50/50. The more P1 is turned to the left, the higher the probability of sending the gate to output "OUT". The more P1 is turned to the right, the higher the probability of sending the gate to output "D".

I send the gate to PINs 9 and 11. So it does not matter if the switch is set to "G" or "M".


Here is a short video that shows the module in action:




The code is very short:
void setup()
{
 pinMode(A2, INPUT); pinMode(A4, INPUT);
 pinMode(8, OUTPUT); pinMode(9, OUTPUT); pinMode(11, OUTPUT);
 digitalWrite(8, LOW); digitalWrite(9, LOW); digitalWrite(11, LOW);
}


boolean gate = false;
boolean oldgate = false;

void loop()
{
 // Check for gate on GRAINS input "A" (Arduino Pin A4)
 // "analogRead()" returns values between 0 and 1023
 // If the value is bigger than 700, this is considered as "gate on"
 gate = analogRead(A4) > 700;

 // React only if state changed
 if (oldgate != gate) {
   if (gate) {
     // Output probability depends on the value of "P1":
     // -> The more P1 is turned to the left, the more "OUT" will be triggered
     // -> The more P1 is turned to the right, the more "D" will be triggered
     if (random(1024) > analogRead(A2)) {
       digitalWrite(8, HIGH); // send gate to "D"
     } else {
       // Send gate to "OUT". Switch setting to "G" or "M" does not
       // matter because both outputs are set
       digitalWrite(9, HIGH); digitalWrite(11, HIGH);
     }
   } else {
     // no gate on input "A" -> set all outputs to zero
     digitalWrite(8, LOW); digitalWrite(9, LOW); digitalWrite(11, LOW);
   }
   oldgate = gate;
 }
}